Power CD-ROM!! 8/Power CD-ROM 8.iso/windows/winutil/explore.cod

Text File | 1992-02-05 | 16.3 KB | 658 lines

' Global Module - Explore Visual Basic
'
' ------------------------------------------------------------------------------------
'               Copyright (C) 1992 Susie Parrent
'
' You may use this software at no charge provided that you agree
' that the author, New Riders Publishing  and Microsoft have no
' warranty,  obligations or liability for any files included in the
' sample files provided herein.
'
' The software is owned by Microsoft or its suppliers and is
' protected by United States copyright laws and international
' treaty provisions.  Therefore, you must treat the software like
' any other copyrighted material (e.g., a book or musical recording)
' EXCEPT that you may either (a) make one copy of the software solely
' for backup or archival purposes, or (b) transfer the software to a
' single hard disk provided you keep the original solely for backup
' or archival purposes.  You may not copy the written materials
' accompanying the software.
'
' It may NOT be used in any training for which a fee is charged
' without the express written permission of the author.

' ------------------------------------------------------------------------

Global Const TRUE = -1
Global Const FALSE = 0

' BackColor (standard RGB colors: form)
Global Const LIGHT_YELLOW = &H80FFFF
Global Const WHITE = &HFFFFFF

Global Const KEY_F1 = &H70

'   Help engine declarations.
'  Commands to pass WinHelp()
Global Const HELP_CONTEXT = &H1     ' Display topic identified by number in Data
Global Const HELP_QUIT = &H2        ' Terminate help
Global Const HELP_INDEX = &H3       ' Display index
Global Const HELP_HELPONHELP = &H4  ' Display help on using help

Declare Function WinHelp Lib "User" (ByVal hWnd As Integer, ByVal lpHelpFile As String, ByVal wCommand As Integer, dwData As Any) As Integer

Global HelpfileName As String

' Constants for various help topics

Global Const HOW_TO_USE = 100&
Global Const ABOUT_FORM1 = 200&
Global Const ABOUT_FORM2 = 300&
Global Const ABOUT_FORM3 = 400&
Global Const ABOUT_FORM4 = 500&
Global Const ABOUT_FORM5 = 600&
Global Const ABOUT_FORM6 = 700&
Global Const NULL = 0&



' Form1 - Explore
' - CloseApp is a general procedure in the CMNPROCS.BAS module
Sub FileExit_Click ()
   CloseApp Form1.hWnd
End Sub

'Form1-Explore
Sub LblNext_Click ()
  Form1.Hide    ' Hide itself
  Form2.Show    ' Show next form
  ExploreHelp HELP_CONTEXT, ABOUT_FORM2
End Sub

'Form1-Explore
Sub HelpAbout_Click ()
   Form7.Show
End Sub

'Form1-Explore
Sub HelpTraining_Click ()
  Form8.Show
End Sub

'Form1-Explore
Sub SettingsColorValue_Click (Index As Integer)
   Select Case Index
     Case 0
       Form1.BackColor = WHITE
       Frame1.BackColor = WHITE
       Label2.BackColor = WHITE
       SettingsColorValue(1).Checked = FALSE
       SettingsColorValue(0).Checked = TRUE
     Case 1
       Form1.BackColor = LIGHT_YELLOW
       Frame1.BackColor = LIGHT_YELLOW
       Label2.BackColor = LIGHT_YELLOW
       SettingsColorValue(0).Checked = FALSE
       SettingsColorValue(1).Checked = TRUE
     End Select
End Sub

'Form1-Explore
Sub Form_Load ()

  Form1.Height = Screen.Height - 100
  Form1.Width = Screen.Width * .45

  Dim TxtBoxContents As String

  TxtBoxContents = Environ$("MAXWINVB") + "\textbox1.txt"
  Open TxtBoxContents For Input Access Read As #1
  FileLen% = LOF(1)
  Form1.Text2.Text = Input$(FileLen%, #1)
  Close #1

End Sub

'Form1-Explore
Sub HelpThisForm_Click ()
  Temp% = WinHelp(hWnd, HelpfileName, HELP_CONTEXT, ByVal ABOUT_FORM1)
End Sub

'Form1-Explore
Sub Form_Resize ()
  Frame1.Height = Form1.ScaleHeight * .85
  Frame1.Width = Form1.ScaleWidth * .9
  Frame1.Top = Form1.ScaleTop + (Form1.ScaleHeight * .05)
  Frame1.Left = Form1.ScaleLeft + (Form1.ScaleWidth * .05)
  Label1.Top = Frame1.Top + (Form1.Height * .05)
  Label1.Left = Frame1.Left + (Form1.Width * .17)
  Text1.Height = Form1.Height * .1
  Text1.Width = Form1.Width * .5
  Text1.Top = Form1.Top + (Form1.Height * .15)
  Text1.Left = Frame1.Left + (Form1.Width * .15)
  Label2.Top = Text1.Top + (Text1.Height * 1.3)
  Label2.Left = Frame1.Left + (Form1.Width * .17)
  Text2.Height = Form1.Height * .4
  Text2.Width = Form1.Width * .8
  Text2.Top = Form1.Top + (Form1.Height * .35)
  Text2.Left = Frame1.Left + (Form1.Width * .05)
  LblNext.Top = Form1.Top + Form1.ScaleHeight - (Form1.ScaleHeight * .07)
  LblNext.Left = Form1.ScaleLeft + (Form1.ScaleWidth * .8)
End Sub

'Form1-Explore
Sub HelpHowto_Click ()
  Temp% = WinHelp(hWnd, HelpfileName, HELP_CONTEXT, ByVal HOW_TO_USE)
End Sub

'Form1-Explore
Sub HelpContents_Click ()
  Temp% = WinHelp(hWnd, HelpfileName, HELP_INDEX, HELP_INDEX)
End Sub


'Form2-Explore
Sub CmdShowPix_Click (Index As Integer)
  Dim I As Integer, J As Integer

  Select Case Index
   Case 0
    Label1.Caption = "This is an example of a simple animation technique:  swapping different icons in and out of a single picture box."
    Picture1.Picture = Picture2(1).Image ' Start with dark moon
    For I = 8 To 1 Step -1
     Picture1.Picture = Picture2(I).Image
      For J = 1 To 30000
        ' Wait loop so animation doesn't run too fast
      Next J
    Next I
   Picture1.Picture = Picture2(1).Image  ' End with dark moon
   Case 1
    Picture1.Picture = Picture2(9).Image
    Label1.Caption = "This bitmap is 4 times larger than the moon pictures.  By setting Picture1's AutoSize property to TRUE, we can make it grow to fit this larger image."
   End Select
End Sub

'Form2-Explore
' - ExploreHelp is a general procedure in the CMNPROCS.BAS module
Sub MnuHelpChoice_Click (Index As Integer)
    Select Case Index
        Case 0
            ExploreHelp HELP_INDEX, HELP_INDEX
        Case 1
            ExploreHelp HELP_CONTEXT, HOW_TO_USE
        Case 2
            ExploreHelp HELP_CONTEXT, ABOUT_FORM2
    End Select
End Sub

'Form2-Explore
Sub MnuHelpTraining_Click ()
    Form8.Show
End Sub

'Form2-Explore
Sub MnuHelpAbout_Click ()
      Form7.Show
End Sub

'Form2-Explore
' - CloseApp is a general procedure in the CMNPROCS.BAS module
Sub MnuFileExit_Click ()
   CloseApp Form2.hWnd
End Sub

'Form2-Explore
Sub LblChangeForm_Click (Index As Integer)

  Select Case Index
    Case 0         ' Back
        LblChangeForm Form2, Form1
        ExploreHelp HELP_CONTEXT, ABOUT_FORM1
    Case 1         ' Next
        LblChangeForm Form2, Form3
        ExploreHelp HELP_CONTEXT, ABOUT_FORM3
  End Select

End Sub

Sub Form_Load ()
  Form1.Height = Screen.Height - 100
  Form1.Width = Screen.Width * .45

End Sub


' Form3 - Explore
Sub Command1_Click ()
    Check1.Value = FALSE
    Check2.Value = FALSE
    Option1.Value = FALSE
    Option2.Value = FALSE
    Option3.Value = FALSE
    Option4.Value = FALSE
    Form3.BackColor = WHITE
End Sub

'Form3-Explore
Sub Option1_Click ()
    Form3.BackColor = LIGHT_YELLOW
End Sub

'Form3-Explore
Sub Option2_Click ()
    Form3.BackColor = WHITE
End Sub

' Form3 - Explore
Sub Check2_Click ()
    If Check2.Value = 1 Then
        Frame2.FontItalic = TRUE
    Else
        Frame2.FontItalic = FALSE
    End If
End Sub

' Form3 - Explore
Sub Check1_Click ()
    If Check1.Value = 1 Then
        Frame2.FontBold = TRUE
    Else
        Frame2.FontBold = FALSE
    End If
End Sub

'Form3-Explore
' - ExploreHelp is a general procedure in the CMNPROCS.BAS module
Sub MnuHelpChoice_Click (Index As Integer)
  Select Case Index
    Case 0
      ExploreHelp HELP_INDEX, HELP_INDEX
    Case 1
      ExploreHelp HELP_CONTEXT, HOW_TO_USE
    Case 2
      ExploreHelp HELP_CONTEXT, ABOUT_FORM3
    Case 4
      Form8.Show
    Case 6
      Form7.Show
  End Select
End Sub

'Form3-Explore
' - CloseApp is a general procedure in the CMNPROCS.BAS module
Sub MnuFileExit_Click ()
   CloseApp Form3.hWnd
End Sub

'Form3-Explore
Sub LblChangeForm_Click (Index As Integer)

  Select Case Index
    Case 0         ' Back
        LblChangeForm Form3, Form2
        ExploreHelp HELP_CONTEXT, ABOUT_FORM2
    Case 1         ' Next
        LblChangeForm Form3, Form4
        ExploreHelp HELP_CONTEXT, ABOUT_FORM4
  End Select

End Sub

Sub Form_Load ()
  Form1.Height = Screen.Height - 100
  Form1.Width = Screen.Width * .45
End Sub



'Form4-Explore
Sub Drive1_Change ()
    On Error GoTo DriveError
    Dir1.Path = Drive1.Drive
    Exit Sub
DriveError:
    If Err = 71 Then        ' Check for "Disk not ready" error
     MsgBox Error$(Err), 0, "Drive Box Error"
     Resume
    Else
     MsgBox Error$(Err), 0, "Drive Box Error"
     Resume Next
    End If
End Sub

'Form4-Explore
Sub Dir1_Change ()
  File1.Path = Dir1.Path
End Sub

'Form4-Explore
' - ExploreHelp is a general procedure in the CMNPROCS.BAS module
Sub MnuHelpChoice_Click (Index As Integer)
  Select Case Index
    Case 0
      ExploreHelp HELP_INDEX, HELP_INDEX
    Case 1
      ExploreHelp HELP_CONTEXT, HOW_TO_USE
    Case 2
      ExploreHelp HELP_CONTEXT, ABOUT_FORM4
    Case 4
      Form8.Show   ' Training Help Form
    Case 6
      Form7.Show   ' About Help Form
  End Select

End Sub

'Form4-Explore
' - CloseApp is a general procedure in the CMNPROCS.BAS module
Sub MnuFileExit_Click ()
   CloseApp Form4.hWnd
End Sub

'Form4-Explore
Sub LblChangeForm_Click (Index As Integer)

  Select Case Index
    Case 0         ' Back
        LblChangeForm Form4, Form3
        ExploreHelp HELP_CONTEXT, ABOUT_FORM3
    Case 1         ' Next
        LblChangeForm Form4, Form5
        ExploreHelp HELP_CONTEXT, ABOUT_FORM5
  End Select

End Sub

'Form4-Explore
Sub File1_DblClick ()
  Dim Path As String
  If Right$(File1.Path, 1) <> "\" Then
    Path = File1.Path + "\"
  Else
    Path = File1.Path
  End If
  Label2.Caption = Path + File1.FileName

End Sub

Sub Form_Load ()
  Form1.Height = Screen.Height - 100
  Form1.Width = Screen.Width * .45
End Sub



' Form5-Explore
Sub Form_Load ()

  Dim I As Integer

  Form1.Height = Screen.Height - 100
  Form1.Width = Screen.Width * .45

  List1.AddItem "0 - Dropdown Combo", 0
  List1.AddItem "1 - Simple Combo", 1
  List1.AddItem "2 - Dropdown list", 2

  Combo1.AddItem "0 - Dropdown Combo"
  Combo2.AddItem "2 - Simple Combo"
  Combo3.AddItem "2 - Dropdown List"

  For I = 2 To 4
    Combo1.AddItem "Item # " + Str$(I)
    Combo2.AddItem "Item # " + Str$(I)
    Combo3.AddItem "Item # " + Str$(I)
  Next I

  Combo1.Top = Form4.Top + (Form4.Height * .55)
  Combo2.Top = Form4.Top + (Form4.Height * .55)
  Combo3.Top = Form4.Top + (Form4.Height * .55)

End Sub

'Form5-Explore
Sub List1_DblClick ()
  Select Case List1.ListIndex
  Case 0
   Combo2.Visible = FALSE
   Combo3.Visible = FALSE
   Label1(1).Visible = TRUE
   Combo1.Visible = TRUE
   Combo1.SetFocus
  Case 1
   Combo1.Visible = FALSE
   Combo3.Visible = FALSE
   Label1(1).Visible = TRUE
   Combo2.Visible = TRUE
   Combo2.SetFocus
  Case 2
   Combo1.Visible = FALSE
   Combo2.Visible = FALSE
   Label1(1).Visible = TRUE
   Combo3.Visible = TRUE
   Combo3.SetFocus
  End Select

End Sub

'Form5-Explore
Sub Combo1_GotFocus ()
    Combo1.Text = "0 - Dropdown Combo"
End Sub

'Form5-Explore
Sub Combo3_GotFocus ()
  Combo3.ListIndex = 0
  Call Combo3_Click
End Sub

Sub Combo3_Click ()
End Sub

'Form5-Explore
Sub LblChangeForm_Click (Index As Integer)

  Combo1.Visible = FALSE
  Combo2.Visible = FALSE
  Combo3.Visible = FALSE
  Label1(1).Visible = FALSE

  Select Case Index
    Case 0         ' Back
        LblChangeForm Form5, Form4
        ExploreHelp HELP_CONTEXT, ABOUT_FORM4
    Case 1         ' Next
        LblChangeForm Form5, Form6
        ExploreHelp HELP_CONTEXT, ABOUT_FORM6
  End Select

End Sub

'Form5-Explore
' - ExploreHelp is a general procedure in the CMNPROCS.BAS module
Sub MnuHelpChoice_Click (Index As Integer)
  Select Case Index
    Case 0
      ExploreHelp HELP_INDEX, HELP_INDEX
    Case 1
      ExploreHelp HELP_CONTEXT, HOW_TO_USE
    Case 2
      ExploreHelp HELP_CONTEXT, ABOUT_FORM5
    Case 4
      Form8.Show   ' Training Help Form
    Case 6
      Form7.Show   ' About Help Form
  End Select


End Sub

'Form5-Explore
Sub Combo2_GotFocus ()
    Combo2.Text = "1 - Simple Combo"
End Sub

'Form5-Explore
' - CloseApp is a general procedure in the CMNPROCS.BAS module
Sub MnuFileExit_Click ()
   CloseApp Form5.hWnd
End Sub

Dim OldHeight As Single
Dim OldWidth As Single

'Form6-Explore
Sub Timer1_Timer ()
   Dim NewLine As String
   NewLine = Chr$(13) + Chr$(10)
   Form6.Picture1.Visible = Not Form6.Picture1.Visible
   Label2.Caption = "Timer Interval = " + Str$(Timer1.Interval) + "." + NewLine + "To change the interval, use the scroll bars."
End Sub

'Form6-Explore
Sub Command1_Click (Index As Integer)
    If Index = 0 Then
      Timer1.Enabled = TRUE
    ElseIf Index = 1 Then
      Timer1.Enabled = FALSE
      Picture1.Visible = FALSE
      Label1(0).Caption = ""
      Label1(1).Caption = ""
      Label2.Caption = "Timer Disabled"
    End If
End Sub

'Form6-Explore
Sub VScroll1_Change ()
  Picture1.Height = OldHeight * (1 + VScroll1.Value * .1)
  Picture1.Width = OldWidth * (1 + VScroll1.Value * .1)
  Label1(1).Caption = "VScroll1 Value= " + Str$(VScroll1.Value)
End Sub

'Form6-Explore
Sub HScroll1_Change ()
  Timer1.Interval = HScroll1.Value
  Label1(0).Caption = "HScroll1 Value= " + Str$(HScroll1.Value)
End Sub

'Form6-Explore
Sub LblBack_Click ()
        Picture1.Height = OldHeight
        Picture1.Width = OldWidth
        VScroll1.Value = VScroll1.Min
        HScroll1.Value = HScroll1.Min
        LblChangeForm Form6, Form5
        ExploreHelp HELP_CONTEXT, ABOUT_FORM5
End Sub

'Form6-Explore
' - ExploreHelp is a general procedure in the CMNPROCS.BAS module
Sub MnuHelpChoice_Click (Index As Integer)
  Select Case Index
    Case 0
      ExploreHelp HELP_INDEX, HELP_INDEX
    Case 1
      ExploreHelp HELP_CONTEXT, HOW_TO_USE
    Case 2
      ExploreHelp HELP_CONTEXT, ABOUT_FORM6
    Case 4
      Form8.Show   ' Training Help Form
    Case 6
      Form7.Show   ' About Help Form
  End Select
End Sub

'Form6-Explore
' - CloseApp is a general procedure in the CMNPROCS.BAS module
Sub MnuFileExit_Click ()
   CloseApp Form6.hWnd
End Sub

Sub Form_Load ()
    Form1.Height = Screen.Height - 100
    Form1.Width = Screen.Width * .45
    OldHeight = Picture1.Height
    OldWidth = Picture1.Width
End Sub

'Form7-Explore -- Help About... Form
Sub Form_Load ()

  Load Form1
  Form1.Top = 0
  Form1.Left = 0
  Load Form2
  Form2.Top = 0
  Form2.Left = 0
  Form3.Top = 0
  Form3.Left = 0
  Load Form3
  Load Form4
  Form4.Top = 0
  Form4.Left = 0
  Load Form5
  Form5.Top = 0
  Form5.Left = 0
  Load Form6
  Form6.Top = 0
  Form6.Left = 0
  Load Form8
  Form8.Top = Screen.Height / 2 - Form7.Height / 2
  Form8.Left = Screen.Width / 2 - Form7.Width / 2

  HelpfileName = Environ$("MAXWINVB") + "\EXPLORE.HLP"

End Sub

'Form7-Explore
Sub Command1_Click ()
    Form7.Hide
End Sub

'Form7-Explore
Sub Timer1_Timer ()
    Timer1.Enabled = FALSE
    Form7.Hide
    Form1.Visible = TRUE
    ExploreHelp HELP_CONTEXT, ABOUT_FORM1
End Sub

'Form8-Explore -- Help Training Form
Sub Command1_Click ()
    Form8.Hide  ' Hide Training Help form
End Sub

'CMNPROCS.BAS -- Since these procedures are in a
' separate module not attached to any form, they
' may be called from anywhere in the application

Dim Success As Integer

'CMNPROCS.BAS
Sub ExploreHelp (HelpCommand As Long, Topic As Long)
   On Error GoTo HelpError
   Success = WinHelp(hWnd, HelpfileName, HelpCommand, ByVal Topic)
   If Success = 0 Then GoTo HelpError
   Exit Sub
HelpError:
   MsgBox "You must set the MAXWINVB environment variable in your AUTOEXEC.BAT file to the drive and directory where you installed this application's files for it to run correctly.", 0, "Environment Not Set"
   CloseApp Screen.ActiveForm.hWnd
End Sub

'CMNPROCS.BAS --
Sub CloseApp (ByVal hWnd As Integer)
   If Success = 0 Then End
   Success = WinHelp(hWnd, HelpfileName, HELP_QUIT, ByVal NULL)
   End
End Sub

'CMNPROCS.BAS
Sub LblChangeForm (CurrentForm As Form, NewForm As Form)

    CurrentForm.Hide  ' Hide itself
    NewForm.Show      ' Move to appropriate form

End Sub